易语言水星浏览器 和 水星框架

水星浏览器和水星框架对象被用来发送命令给浏览器以及在事件中获取状态信息。 每个水星浏览器对象都包含一个主框架对象, 主框架对象代表页面的顶层 iframe ; 同时每个浏览器对象可以包含零个或多个的子框架对象, 分别代表不同的子 iframe 。 例如, 一个浏览器加载了两个 iframe , 则该浏览器对象拥有三个框架对象( 顶层 iframe 和 两个子 iframe )。

获取主框架

.版本 2
.支持库 ecef

.子程序 _按钮_演示_被单击
.局部变量 浏览器, 水星浏览器
.局部变量 主框架, 水星框架

浏览器 ＝ 水星铬浏览框1.取浏览器 (hwnd)

主框架 ＝ 浏览器.取主框架 ()

使用框架

.版本 2
.支持库 ecef

.子程序 _按钮_演示_被单击
.局部变量 浏览器, 水星浏览器
.局部变量 主框架, 水星框架

浏览器 ＝ 水星铬浏览框1.取浏览器 (hwnd)

主框架 ＝ 浏览器.取主框架 ()

' 在框架中加载一个URL
主框架.加载URL (“http://itwitch.cc/ecef”)

框架的列举方法

.版本 2
.支持库 ecef

.子程序 _按钮_演示_被单击
.局部变量 浏览器, 水星浏览器
.局部变量 框架名称数组, 文本型, , "0"
.局部变量 框架标识符数组, 长整数型, , "0"
.局部变量 框架数组, 水星框架, , "0"
.局部变量 框架, 水星框架

浏览器 ＝ 水星铬浏览框1.取浏览器 (hwnd)

' 框架的列举方式有以下几种形式:

' 1.获取所有框架的名称
框架名称数组 ＝ 浏览器.取所有框架名称 ()

' 从名称索引框架
.如果真 (取数组成员数 (框架名称数组) ＞ 0)
    框架 ＝ 浏览器.从名称取框架 (框架名称数组 [1])
.如果真结束

' 2.获取所有框架的标识符
框架标识符数组 ＝ 浏览器.取所有框架标识符 ()

' 从标识符索引框架
.如果真 (取数组成员数 (框架标识符数组) ＞ 0)
    框架 ＝ 浏览器.从标识符取框架 (框架标识符数组 [1])
.如果真结束

' 3.获取所有框架对象
框架数组 ＝ 浏览器.取所有框架 ()

' 直接使用框架
.如果真 (取数组成员数 (框架数组) ＞ 0)
    框架 ＝ 框架数组 [1]
.如果真结束

文件下载

浏览器产生下载请求时(包含调用方法 : 水星浏览器.启动下载() ), 事件 "浏览器即将下载" 将会被触发。 参数对象 "下载项" 指示了下载文件的状态信息。 执行类型方法 " 下载项.保存到() " 方法以允许浏览器下载资源并为资源提供磁盘存储位置。 省略调用此方法则浏览器将会忽略下载请求。

.版本 2
.支持库 ecef

.子程序 _水星铬浏览框1_浏览器即将下载
.参数 浏览器, 水星浏览器, 参考
.参数 下载项, 水星下载项, 参考
.参数 建议名称, 文本型

' 允许浏览器下载资源并为资源提供磁盘存储位置, 如果希望由用户决定保存路径,则设置第二个
' 参数为真, 设置后浏览器将忽略第一个参数并弹出一个文件选择对话框供用户选择保存路径。
下载项.保存到 (“d:\” ＋ 建议名称, 假)

如果通过了资源的下载请求浏览器将会每隔一秒触发一次事件 "浏览器下载进度已更新" 以告知当前资源的下载状态。要控制资源的下载行为可以使用参数 "下载项" 提供的类型方法: 下载项.取消下载() , 下载项.暂停下载() , 下载项.恢复下载() 等方法进行设置。

.版本 2
.支持库 ecef

.子程序 _水星铬浏览框1_浏览器下载进度已更新
.参数 浏览器, 水星浏览器, 参考
.参数 下载项, 水星下载项, 参考

下载项.暂停下载 ()

' 处理业务代码...

下载项.恢复下载 ()

上下文菜单

浏览器上下文菜单产生的事件由 "浏览器菜单即将打开" 传递, 如果希望实现自定义菜单则应实现事件 "浏览器显示自定义菜单" 。 参数 "菜单信息" 提供了与菜单上下文有关的状态信息, 包括请求的来源, 页面地址以及页面期望创建的菜单类型等等。 参数 "菜单" 提供了一组菜单功能实现接口, 详细信息见类型说明。

.版本 2
.支持库 ecef
.支持库 spec

.子程序 _水星铬浏览框1_浏览器菜单即将打开
.参数 浏览器, 水星浏览器, 参考
.参数 框架, 水星框架, 参考
.参数 菜单信息, 水星菜单信息, 参考
.参数 菜单, 水星菜单, 参考
.局部变量 子菜单, 水星菜单

调试输出 (“浏览器菜单即将打开”)

' 用户在浏览器中打开上下文菜单时调用此事件。

' 参数 | 菜单信息 | 提供了菜单有关的上下文信息

调试输出 (“菜单位置: ”, 菜单信息.取坐标X (), 菜单信息.取坐标Y ())

' 参数 | 菜单 | 提供了一组默认的菜单功能接口。

' 添加一个菜单项
菜单.添加菜单项 (2000, “测试菜单”)

' 添加分隔符
菜单.添加分隔符 ()

' 添加复选菜单
菜单.添加复选菜单项 (2001, “测试复选菜单”)

' 添加单选菜单
菜单.添加单选菜单项 (2002, “测试单选菜单1”, 990)
菜单.添加单选菜单项 (2003, “测试单选菜单2”, 990)

' 添加子菜单
子菜单 ＝ 菜单.添加子菜单项 (2004, “测试子菜单”)

子菜单.添加菜单项 (3001, “子菜单项”)

显示自定义菜单

.版本 2
.支持库 ecef
.支持库 spec

.子程序 _水星铬浏览框1_浏览器显示自定义菜单, 逻辑型
.参数 浏览器, 水星浏览器, 参考
.参数 框架, 水星框架, 参考
.参数 菜单信息, 水星菜单信息, 参考
.参数 菜单, 水星菜单, 参考
.参数 菜单回调, 水星菜单回调, 参考

调试输出 (“浏览器显示自定义菜单”)

' 如果希望显示自定义菜单,则在此事件中返回真以使用自定义菜单代替系统菜单。
' 使用自定义菜单时通过参数 | 菜单回调 | 提供菜单选择结果

' 菜单回调.执行命令 (2001, #事件标志.NONE)
' 返回 (真)

返回 (假)